plasma-manager
Home Manager module for declarative KDE Plasma configuration. Manages panel layouts, widgets, shortcuts, themes, and KDE application settings through Nix.
Setup
# flake.nix
{
inputs = {
nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
home-manager.url = "github:nix-community/home-manager";
plasma-manager = {
url = "github:nix-community/plasma-manager";
inputs.nixpkgs.follows = "nixpkgs";
inputs.home-manager.follows = "home-manager";
};
};
outputs = { home-manager, plasma-manager, ... }: {
homeConfigurations.myuser = home-manager.lib.homeManagerConfiguration {
modules = [ plasma-manager.homeManagerModules.plasma-manager ];
};
};
}Example config
{ pkgs, ... }:
{
home.stateVersion = "23.11";
programs.plasma = {
enable = true;
workspace = {
clickItemTo = "open";
lookAndFeel = "org.kde.breezedark.desktop";
cursor = {
theme = "Bibata-Modern-Ice";
size = 32;
};
iconTheme = "Papirus-Dark";
wallpaper = "${pkgs.kdePackages.plasma-workspace-wallpapers}/share/wallpapers/Patak/contents/images/1080x1920.png";
};
hotkeys.commands."launch-konsole" = {
name = "Launch Konsole";
key = "Meta+Alt+K";
command = "konsole";
};
fonts = {
general = {
family = "JetBrains Mono";
pointSize = 12;
};
};
desktop.widgets = [
{
plasmusicToolbar = {
position = {
horizontal = 51;
vertical = 100;
};
size = {
width = 250;
height = 250;
};
};
}
];
panels = [
# Windows-like panel at the bottom
{
location = "bottom";
widgets = [
# We can configure the widgets by adding the name and config
# attributes. For example to add the the kickoff widget and set the
# icon to "nix-snowflake-white" use the below configuration. This will
# add the "icon" key to the "General" group for the widget in
# ~/.config/plasma-org.kde.plasma.desktop-appletsrc.
{
name = "org.kde.plasma.kickoff";
config = {
General = {
icon = "nix-snowflake-white";
alphaSort = true;
};
};
}
# Or you can configure the widgets by adding the widget-specific options for it.
# See modules/widgets for supported widgets and options for these widgets.
# For example:
{
kickoff = {
sortAlphabetically = true;
icon = "nix-snowflake-white";
};
}
# Adding configuration to the widgets can also for example be used to
# pin apps to the task-manager, which this example illustrates by
# pinning dolphin and konsole to the task-manager by default with widget-specific options.
{
iconTasks = {
launchers = [
"applications:org.kde.dolphin.desktop"
"applications:org.kde.konsole.desktop"
];
};
}
# Or you can do it manually, for example:
{
name = "org.kde.plasma.icontasks";
config = {
General = {
launchers = [
"applications:org.kde.dolphin.desktop"
"applications:org.kde.konsole.desktop"
];
};
};
}
# If no configuration is needed, specifying only the name of the
# widget will add them with the default configuration.
"org.kde.plasma.marginsseparator"
# If you need configuration for your widget, instead of specifying the
# the keys and values directly using the config attribute as shown
# above, plasma-manager also provides some higher-level interfaces for
# configuring the widgets. See modules/widgets for supported widgets
# and options for these widgets. The widgets below shows two examples
# of usage, one where we add a digital clock, setting 12h time and
# first day of the week to Sunday and another adding a systray with
# some modifications in which entries to show.
{
digitalClock = {
calendar.firstDayOfWeek = "sunday";
time.format = "12h";
};
}
{
systemTray.items = {
# We explicitly show bluetooth and battery
shown = [
"org.kde.plasma.battery"
"org.kde.plasma.bluetooth"
];
# And explicitly hide networkmanagement and volume
hidden = [
"org.kde.plasma.networkmanagement"
"org.kde.plasma.volume"
];
};
}
];
hiding = "autohide";
}
# Application name, Global menu and Song information and playback controls at the top
{
location = "top";
height = 26;
widgets = [
{
applicationTitleBar = {
behavior = {
activeTaskSource = "activeTask";
};
layout = {
elements = [ "windowTitle" ];
horizontalAlignment = "left";
showDisabledElements = "deactivated";
verticalAlignment = "center";
};
overrideForMaximized.enable = false;
titleReplacements = [
{
type = "regexp";
originalTitle = "^Brave Web Browser$";
newTitle = "Brave";
}
{
type = "regexp";
originalTitle = ''\\bDolphin\\b'';
newTitle = "File manager";
}
];
windowTitle = {
font = {
bold = false;
fit = "fixedSize";
size = 12;
};
hideEmptyTitle = true;
margins = {
bottom = 0;
left = 10;
right = 5;
top = 0;
};
source = "appName";
};
};
}
"org.kde.plasma.appmenu"
"org.kde.plasma.panelspacer"
{
plasmusicToolbar = {
panelIcon = {
albumCover = {
useAsIcon = false;
radius = 8;
};
icon = "view-media-track";
};
playbackSource = "auto";
musicControls.showPlaybackControls = true;
songText = {
displayInSeparateLines = true;
maximumWidth = 640;
scrolling = {
behavior = "alwaysScroll";
speed = 3;
};
};
};
}
];
}
];
window-rules = [
{
description = "Dolphin";
match = {
window-class = {
value = "dolphin";
type = "substring";
};
window-types = [ "normal" ];
};
apply = {
noborder = {
value = true;
apply = "force";
};
# `apply` defaults to "apply-initially"
maximizehoriz = true;
maximizevert = true;
};
}
];
powerdevil = {
AC = {
powerButtonAction = "lockScreen";
autoSuspend = {
action = "shutDown";
idleTimeout = 1000;
};
turnOffDisplay = {
idleTimeout = 1000;
idleTimeoutWhenLocked = "immediately";
};
};
battery = {
powerButtonAction = "sleep";
whenSleepingEnter = "standbyThenHibernate";
};
lowBattery = {
whenLaptopLidClosed = "hibernate";
};
};
kwin = {
edgeBarrier = 0; # Disables the edge-barriers introduced in plasma 6.1
cornerBarrier = false;
scripts.polonium.enable = true;
};
kscreenlocker = {
lockOnResume = true;
timeout = 10;
};
#
# Some mid-level settings:
#
shortcuts = {
ksmserver = {
"Lock Session" = [
"Screensaver"
"Meta+Ctrl+Alt+L"
];
};
kwin = {
"Expose" = "Meta+,";
"Switch Window Down" = "Meta+J";
"Switch Window Left" = "Meta+H";
"Switch Window Right" = "Meta+L";
"Switch Window Up" = "Meta+K";
};
};
#
# Some low-level settings:
#
configFile = {
baloofilerc."Basic Settings"."Indexing-Enabled" = false;
kwinrc."org.kde.kdecoration2".ButtonsOnLeft = "SF";
kwinrc.Desktops.Number = {
value = 8;
# Forces kde to not change this value (even through the settings app).
immutable = true;
};
kscreenlockerrc = {
Greeter.WallpaperPlugin = "org.kde.potd";
# To use nested groups use / as a separator. In the below example,
# Provider will be added to [Greeter][Wallpaper][org.kde.potd][General].
"Greeter/Wallpaper/org.kde.potd/General".Provider = "bing";
};
};
};
}How it works
plasma-manager writes to ~/.config/ KDE config files via Home Manager activation scripts. On first run or after changes, Plasma reads the updated config files.
Note: some settings require a logout/login to take effect.
Capturing Your Current Configuration with rc2nix
To make it easier to migrate to plasma-manager, and to help maintain your Nix configuration when not using overrideConfig, this project includes a tool called rc2nix.
This tool will read KDE configuration files and translate them to Nix. The translated configuration is written to standard output. This makes it easy to:
- Generate an initial Plasma Manager configuration file.
- See what settings are changed by a GUI tool by capturing a file before and after using the tool and then using diff.
Keep in mind that the rc2nix module isn’t perfect and often will give somewhat suboptimal configurations (it will in some cases prefer using the files module when better configurations can be achieved using higher-level modules). However, it is still a useful tool to quickly get your configuration up and running or converting config-files generated by the gui settings app to nix expressions.
To run the rc2nix tool without having to clone this repository run the following shell command:
nix run github:nix-community/plasma-manager